PCF8591-DA和AD转换器读写程序
发布时间:2020-10-02 14:37:24
发布时间:2020-10-02 14:37:24
PCF8591读写程序
(一)、PCF8591
1、引脚说明
ANI0~ANI3 为模拟信号输入端,不使用的输入端应接地
A0~A2 地址输入端
GND、VCC 地和电源端(+5V)
SDA 为I2C数据输入与输出端
SCL 为I2C时钟输入端
EXT 内外部时钟选择端,使用内部时钟时接地,使用外部时钟时接+5V
OSC 外部时钟输入、内部时钟输出端,不使用时应悬空
AGND 模拟信号地
VREF 基准电压输入端
AOUT D/A转换后的电压输出端
2、功能说明
PCF8591是具有I2C总线接口的8位A/D及D/A转换器,具有4路A/D输入,1路D/A输出。PCF8591采用典型的I2C总线接口器件寻址方法,即总线地址由器件地址(1001)、引脚地址(由A0~A2接地或+5V来确定,接地代表0;接+5V代表1)、方向位(即R/W)组成。因此,在I2C总线系统中最多可接8个这样的器件。
D7 | D6 | D5 | D4 | D3 | D2 | D1 | D0 |
1 | 0 | 0 | 1 | A2 | A1 | A0 | R/W |
R/W=1表示读操作,R/W=0表示写操作。本例将A0~A2接地,则读地址为91H;写地址为90H。
地址字节:由器件地址、引脚地址、方向位组成,它是通信时主机发送的第一字节数据。
控制字节:用于控制PCF8951的输入方式、输入通道、D/A转换等,是通信时主机发送的第二字节数据,其格式如下:
D7 | D6 | D5 | D4 | D3 | D2 | D1 | D0 |
未用 (写0) | D/A输出允许位 0为禁止 1为允许 | A/D输入方式选择位00:4路单端输入 01:3路差分输入 10:单端与差分 11:2路差分输入 | 未用 (写0) | 自动增益选择位 0为禁用 1为启用 | AD通道选择位 00:选择通道0 01:选择通道1 10:选择通道2 11:选择通道3 | ||
A/D输入方式选择说明:
3、通信格式
第一字节 | 第二字节 | 第三字节 |
写入器件地址(90H) | 写入控制字节 | 要写入的数据 |
向PCF8591写入格式(高位在前) |
第一字节 | 第二字节 | 第三字节 | 第四字节 |
写入器件地址(90H写) | 写入控制字节 | 写入器件地址(91H读) | 读出一字节数据 |
从PCF8591读数据格式(高位在前) | |||
(二)、I2C总线
1、I2C总线数据位的传输
它通过2根线:串行数据线(SDA)和串行时钟线(SCL)组成。连接到总线上的每一个器件都有一个唯一的地址,而且都可以作为一个发生器或接收器,SDA和SCL都是双向线路,分别通过一个电阻连接到电源(+5V)端。前提是连接到总线上的器件的SDA和SCL端必须是漏极或集电极开路型。I2C总线上的数据传输速率在标准模式下可达100Kb/s,快速模式可达400Kb/s,高速模式下可达3.4Mb/s。连接到总线的器件数量只由总线的电容(400PF)限制决定。
I2C总线上每传输一个数据位必须产生一个时钟脉冲,I2C总线上数据传输的有效性要求SDA线上的数据必须在时钟线SCL的高电平期间保存稳定,数据线的改变只能在时钟线为低电平期间。在标准模式下,高低电平宽度必须大于4.7us(即每次时钟线需延时4.7us后才能改变)。
2、I2C总线数据的传输
数据传输的字节格式
发送到SDA线上的每一个字节必须为8位,每次发送的字节数量不受限制,从机在接收完一个字节后向主机发送一个应答位,主机在收到从机应答后才会发送第二字节数据,发送数据时先发数据的最高位。
数据传输中的应答
相应的应答位由接收方(从机)产生,在应答的时钟脉冲期间,发送方(主机)应释放SDA线(使其为高电平)。在应答过程中,接收方(从机)必须将数据线SDA拉低,使它在这个时钟脉冲的高电平期间保持稳定的低电平。
3、I2C总线的传输协议
寻址字节
主机产生起始条件后,发送的第一字节为寻址字节,该字节的前7位为从机地址,最低位决定了传输的方向,该最低位为“0”表示主机写数据到从机,“1”表示主机从从机中读数据。从机地址由一个固定的部分(如高4位1001)和可编程部分(如低3位A0~A2)及一个方向位(R/W)组成。
传输格式
主机产生起始条件后,首先发送一个寻址字节,收到从机应答后,接着就传输数据,数据传输一般由主机产生的停止位终止。但如果主机仍希望在总线上通信,则它可以产生重复起始条件和寻址另一个从机,而不必产生一个停止条件。
主机写数据到从机的通信格式如下:
1 | 2 | 3 | 4 | 5 | 6 | 7 | N | N-1 |
主机产生起始位 | 发从机地址90H | 等待从机应答 | 发送数据 | 等待从机应答 | 发送数据 | 等待从机应答 | 。。。。 | 停止位 |
主机从从机中读数据的通信格式如下:
1 | 2 | 3 | 4 | 5 | 6 | 7 | N | N-1 |
主机产生起始位 | 发从机地址91H | 等待从机应答 | 接收从机发出的数据 | 向从机应答 | 接收从机发出的数据 | 向从机应答 | 。。。。 | 主机产生停止位 |
原理图如下:
汇编源代码如下:
;//本测试程序将AIN0通道的模拟电压进行A/D转换后,将数字量通过LED数码管显示出来,同时再将该数字
;//量写入PCF8591中,通过其内部的D/A转换为模拟电压输出驱动LED发光二极管。
ACK BIT 20H.0 ;应答标志位ACK=0表示无应答
SCL BIT P1.0 ;时钟线
SDA BIT P1.1 ;数据线
WADD EQU 21H ;器件地址(即从地址)
SUBD EQU 22H ;器件内部地址(即子地址)
NUMBR EQU 23H ;需读取的字节数
NUMBW EQU 24H ;需写入的字节数
RDATA EQU 25H ;读出数据的存放首地址
WDATA EQU 26H ;写入数据的存放首地址
ORG 0000H
SJMP MAIN
ORG 0030H
MAIN: MOV WADD,#90H ;写入PCF8591的地址
MOV P0,#0FFH ;关闭显示
MOV P2,#0FFH
MOV SUBD,#40H ;写入PCF8591的控制字
MOV NUMBR,#1 ;写入需读取的字节数
MOV NUMBW,#1 ;写入需写入的字节数
MOV RDATA,#30H ;送入首地址
MOV WDATA,#40H ;送入首地址
MOV 50H,#0 ;显示的百位清零
MOV 51H,#0 ;显示的十位清零
MOV 52H,#0 ;显示的个位清零
M1: LCALL READI2C ;读PCF8591子程序
MOV 40H,30H
MOV NUMBR,#1
MOV NUMBW,#1
LCALL DAT
LCALL DISPLAY
LCALL WRITEI2C ;写PCF8591子程序
SJMP M1
;数据处理子程序
DAT: MOV A,30H
MOV B,#100
DIV AB
MOV 50H,A
MOV A,#10
XCH A,B
DIV AB
MOV 51H,A
MOV 52H,B
RET
;显示子程序
DISPLAY: MOV DPTR,#TAB
MOV A,50H
MOVC A,@A+DPTR
MOV P0,A
MOV P2,#01H
LCALL TIM2MS
MOV A,51H
MOVC A,@A+DPTR
MOV P0,A
MOV P2,#02H
LCALL TIM2MS
MOV A,52H
MOVC A,@A+DPTR
MOV P0,A
MOV P2,#04H
LCALL TIM2MS
RET
;2ms延时子程序
TIM2MS: MOV R6,#2
TIM1: MOV R5,#250
TIM2: NOP
NOP
DJNZ R5,TIM2
DJNZ R6,TIM1
RET
TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0BFH,8CH,0C6H,0C7H,86H,0FFH ;共阳数码管
;从I2C总线读取N个字节数据子程序
READI2C: LCALL STARTI2C ;启动I2C总线
MOV A,WADD ;送入器件地址
LCALL WI2C ;向I2C总线发送一个字节数据子程序
LCALL RACK ;读取从机应答位子程序
JNB ACK,ROUT ;判断从机有无应答ACK=0则无应答
MOV A,SUBD ;送入器件内部地址
LCALL WI2C
LCALL RACK
LCALL STARTI2C
MOV A,WADD
INC A ;改总线为读取状态
LCALL WI2C
LCALL RACK
JNB ACK,READI2C
MOV R0,RDATA ;送入读出数据的存放首地址
RI2C2: LCALL RI2C
MOV @R0,A
DJNZ NUMBR,RI2C1 ;判断字节读取完否
LCALL NMACK ;调主机非应答子程序
ROUT: LCALL STOPI2C ;调I2C总线停止子程序
MOV RDATA,#30H
RET
RI2C1: LCALL MACK ;调主机应答子程序
INC R0
SJMP RI2C2
;向I2C总线发送N个字节数据子程序
WRITEI2C: LCALL STARTI2C ;启动I2C总线
MOV A,WADD ;送入器件地址
LCALL WI2C ;向I2C总线发送一个字节数据子程序
LCALL RACK ;读取从机应答位子程序
JNB ACK,WOUT ;判断从机有无应答ACK=0则无应答
MOV A,SUBD ;送入器件内部地址
LCALL WI2C
LCALL RACK
JNB ACK,WOUT
MOV R0,WDATA ;送入写入数据的存放首地址
WI2C1: MOV A,@R0
LCALL WI2C
LCALL RACK
JNB ACK,WRITEI2C
INC R0
DJNZ NUMBW,WI2C
WOUT: LCALL STOPI2C
MOV WDATA,#40H
RET
;I2C总线启动子程序
STARTI2C: SETB SDA
SETB SCL
NOP
NOP
NOP
NOP
NOP
CLR SDA
NOP
NOP
NOP
NOP
NOP
CLR SCL
RET
;I2C总线停止子程序
STOPI2C: CLR SDA
SETB SCL
NOP
NOP
NOP
NOP
NOP
SETB SDA
RET
;主机应答子程序
MACK: CLR SDA
SETB SCL
NOP
NOP
NOP
NOP
NOP
CLR SCL
RET
;主机非应答子程序
NMACK: SETB SDA
SETB SCL
NOP
NOP
NOP
NOP
NOP
CLR SCL
RET
;向I2C总线发送一个字节数据子程序
WI2C: MOV R7,#8
WLP: RLC A
MOV SDA,C
NOP
SETB SCL
NOP
NOP
NOP
NOP
NOP
CLR SCL
DJNZ R7,WLP
RET
;从I2C总线读取一个字节数据子程序
RI2C: MOV R7,#8
CLR A
SETB SDA
NOP
RLP: SETB SCL
NOP
NOP
MOV C,SDA
NOP
CLR SCL
RLC A
NOP
NOP
NOP
NOP
DJNZ R7,RLP
NOP
RET
;读取从机应答位子程序
RACK: SETB SDA
NOP
NOP
SETB SCL
CLR ACK
NOP
NOP
MOV C,SDA
JC ACKEND
SETB ACK
ACKEND: NOP
CLR SCL
NOP
RET
END
(注:文档可能无法思考全面,请浏览后下载,供参考。可复制、编制,期待你的好评与关注)