/一个周边简支的圆盘，其中心受到一个冲杆的周期作用(假定冲杆是刚性的)，需要进行圆盘在冲杆的周期作用下的塑性分析。本实例的模型简图如图19.1所示，材料特性如下所示，塑性时的应力－应变关系如表19.1，载荷历史如表19.2所示。

弹性模量：EX=70000，泊松比：NUXY=0.325

/PREP7

/TITLE,Circular Plate Loaded by a Circular Punch - Kinematic Hardening

!* 下面定义建模分析时需要的参数

EXX=70000

RPL=65

RPU=5

H=6.5

STS1=55

STN1=STS1/EXX

STS2=112

STN2=0.00575

STS3=172

STN3= 0.02925

STS4=241

STN4= 0.1

NEX=15

NET=2

NEX1=nint(0.8*NET)

NEX2=NEX-NEX1

!*

ET,1,42,,,1 ！定义单元PLANE42，设置为轴对称

!*

MP,EX,1,EXX ！定义材料属性

MP,NUXY,1,0.325

!*

TB,KINH,1,1,4, ！定义多线性随动强化准则

TBPT,,STN1,STS1

TBPT,,STN2,STS2

TBPT,,STN3,STS3

TBPT,,STN4,STS4

!* 创建节点

N,1,RPL,,,,,,

N,2,0,,,,,,

N,3,,H/2,,,,,

!* 创建关键点

K,1,,-(H/2),,

K,2,RPU,-(H/2),,

K,3,RPL,-(H/2),,

KGEN,2,ALL, , , ,H, ,3,0 ！复制并平移关键点

!* 创建直线段

L,1, 2

L,4, 5

L,2, 3

L,5,6

!* 用关键点创建面

A,1,2,5,4

A,2,3,6,5

!* 对线进行网格控制

LESIZE,1, , ,NEX1

LESIZE,2, , ,NEX1

LESIZE,3, , ,NEX2,2.5

LESIZE,4, , ,NEX2,2.5

LESIZE,5, , ,NET

LESIZE,6, , ,NET

LESIZE,7, , ,NET

!*

AMESH,ALL ！对面划分网格

!*

NUMMRG,NODE, , , ,LOW ！合并重复节点

NUMCMP,NODE

!*

CP,1,UY,3,7,9 ！定义耦合自由度

!*

D,1,UY ！定义位移约束条件

NSEL,S,LOC,X,0

D,ALL,UX

NSEL,ALL

!* 下面开始求解

/SOLU

!*

ANTYPE,0 ！指定分析类型

OUTRES,ALL,ALL ！设置输出控制

PRED,ON ！打开预测器

!* 施加并输出第一个载荷步

F,3,FY,0

TIME,1e-6

AUTOTS,1

NSUBST,1, , ,1

KBC,0

LSWRITE,1,

!* 施加并输出第二个载荷步

F,3,FY,-6000

TIME,1

NSUBST,10, , ,1

LSWRITE,2,

!* 施加并输出第三个载荷步

F,3,FY,750

TIME,2

LSWRITE,3,

!* 施加并输出第四个载荷步

F,3,FY,-6000

TIME,3

LSWRITE,4,

!* 求解所有4个载荷步

LSSOLVE,1,4,1,

FINISH

!* 进入通用后处理器

/POST1

SET,LAST 选定最后一个载荷子步

PLDISP,1 绘制变形图

!*

PLNSOL,EPPL,EQV,1,1 ！绘制等效塑性应变

PLNSOL,EPEL,EQV,1,1 ！绘制等效弹性应变

!* 进入时间－历程后处理

/POST26

ESOL,2,3,3 ,S,Y,SY_2 ！定义变量

ESOL,3,3,3 ,EPEL,Y,EPELY_3

ESOL,4,3,3 ,EPPL,Y,EPPLY_4

ADD,5,3,4,,EPTLY ！对变量进行运算

!*

/AXLAB,X,Y-Strain

/AXLAB,Y,Y-Stress

!* ！绘制应力－应变曲线

XVAR,5

PLVAR,2,

FINISH

ANSYS塑性变形模拟例子